Arma 3 - Gewitter

Habe vor kurzem ein Skriptfetzen gefunden, welches ein ziemlich beeindruchendes Gewitter generiert. Einziges Handycap, es ist sofort voll da. Sprich es gibt keine langsame Unwetter-Entwicklung . man hat es gleich zu 100%.

Man kann es per Trigger starten oder auch zb. in die Init.sqf eintragen:

h = [] spawn { 
 private _fncLightning = { 
  params [ 
   ["_centre", position player, [[]]], 
   ["_radius", 300, [0]], 
   ["_dir", random 360, [0]] 
  ]; 
  private _pos = _centre getPos [_radius, _dir]; 
  private _bolt = createVehicle ["LightningBolt", _pos, [], 0, "none"]; 
  _bolt setPosATL _pos; 
  _bolt setDamage 1; 
 
  private _light = "#lightpoint" createVehiclelocal _pos; 
  _light setPosATL (_pos vectorAdd [0,0,10]); 
  _light setLightDayLight true; 
  _light setLightBrightness 300; 
  _light setLightAmbient [0.05, 0.05, 0.1]; 
  _light setlightcolor [1, 1, 2]; 
 
  sleep 0.1; 
  _light setLightBrightness 0; 
  sleep (random 0.1); 
 
  private _lightning = (selectRandom ["lightning1_F","lightning2_F"]) createVehiclelocal [100,100,100]; 
  _lightning setdir _dir; 
  _lightning setpos _pos; 
 
  for "_i" from 0 to (3 + random 1) do { 
   private _time = time + 0.2; 
   _light setLightBrightness (100 + random 100); 
   waituntil { 
    time > _time 
   }; 
  }; 
 
  deletevehicle _lightning; 
  deletevehicle _light; 
 }; 
  
 while {true} do { 
  _intensity = 2 + floor (random 3); 
  for "_i" from 0 to (_intensity -1) do { 
   [position player, linearConversion [0, 1, random 1, 300, 800]] call _fncLightning; 
  }; 
  sleep 2 + (random 2); 
 }; 
};