ACCESS DENIED!

Error!

ACCESS GRANTED!

Success!

ARMA 3 Editor:

 Spritverbrauch für Fahrzeuge ändern

Titelbild

Spritverbrauch für Fahrzeuge ändern


Autor: greni

Zur Regelung des Spritverbrauches habe ich nach einem Skript gesucht, welches den "Standard" Spritverbrauch in den Mission ändert. Hiezu wurde ich im Bohemia Forum fündig und deckt genau das ab, was ich gesucht habe. Meine Idee war, das die Spieler in meinen Missionen auch ein Problem mit dem Spritverbrauch bekommen können. Dieses Skript ist einfach zu händeln.

Beispiel:

// Zeit in Minuten bis Tank leer bei stehendem Fahrzeug
kp_neutral_consumption = 20;
// Zeit in Minuten bis Tank leer bei normaler Fahrweise
_kp_normal_consumption = 15;
// Zeit in Minuten bis Tank leer mit andauernder Höchstgeschwindigkeit
_kp_max_consumption = 9;

 

Angesprochen wird das Skript über die initPlayer.sqf mit:

player addEventHandler ["GetInMan", {[ _this select 2] execVM "kp_fuel_consumption.sqf";}];

oder direkt in die Init der Spielereinheit

this addEventHandler ["GetInMan", {[ _this select 2] execVM "kp_fuel_consumption.sqf";}];

Das Skript ist als Datei als Download beigelegt.

 

if (!isServer) exitWith {};
/*
kp_fuel_consumption.sqf
Author: Wyqer
Website: www.killahpotatoes.de
Date: 2017-02-02

Description:
This script handles the fuel consumption of vehicles, so that refueling will be necessary more often.

Parameters:
_this select 0 - OBJECT - Vehicle

Method:
execVM

Example for initPlayerLocal.sqf:
player addEventHandler ["GetInMan", {[ _this select 2] execVM "kp_fuel_consumption.sqf";}];
*/

private ["_kp_neutral_consumption","_kp_normal_consumption","_kp_max_consumption"];

/*
CONFIG
*/
// Time in Minutes till a full tank depletes when the vehicle is standing with running engine
_kp_neutral_consumption = 20;
// Time in Minutes till a full tank depletes when the vehicle is driving
_kp_normal_consumption = 15;
// Time in Minutes till a full tank depletes when the vehicle is driving at max speed
_kp_max_consumption = 9;

/*
DO NOT EDIT BELOW
*/

if (isNil "kp_fuel_consumption_vehicles") then {
    kp_fuel_consumption_vehicles = [];
};

if (!((_this select 0) in kp_fuel_consumption_vehicles)) then {
    kp_fuel_consumption_vehicles pushBack (_this select 0);
    while {local (_this select 0)} do {
        if (isEngineOn (_this select 0)) then {
            if (speed (_this select 0) > 5) then {
                if (speed (_this select 0) > (getNumber (configFile >> "CfgVehicles" >> typeOf (_this select 0) >> "maxSpeed") * 0.9)) then {
                    (_this select 0) setFuel (fuel (_this select 0) - (1 / (_kp_max_consumption * 60)));
                } else {
                    (_this select 0) setFuel (fuel (_this select 0) - (1 / (_kp_normal_consumption * 60)));
                };
            } else {
                (_this select 0) setFuel (fuel (_this select 0) - (1 / (_kp_neutral_consumption * 60)));
            };
        };
        uiSleep 1;
    };
    kp_fuel_consumption_vehicles deleteAt (kp_fuel_consumption_vehicles find (_this select 0));
};

 

 



Beispiel:
kp_fuel_consumption.sqf

Die letzten Einträge


x
Diese Seite verwendet Cookies. Durch die Nutzung unserer Seite erklären Sie sich damit einverstanden, dass wir Cookies setzen. Weitere Informationen. OK